コンテンツにスキップ

右クリックの仕様をWindows10に戻す

Warning

本記事はWindows 11 Version 23H2 (OS Build 22621.4037)で動作確認しています。 OSレジストリを変更するため、変更によってPCに問題が発生する可能性があります。 本記事の内容を実行する場合は、自己責任でお願いします。

Windows11では、右クリックの動作が変更されています。
筆者はそれがうざすぎて、Windows10のように戻したいと思いました。
Windows10のように、右クリックでコンテキストメニューを表示するように変更する方法を説明します。

手順

色々調べた結果、レジストリエディタを使って変更する方法が見つかりました。

筆者は教育現場で数百のPCを扱うため、バッチファイルを作成して一括で変更することにしました。

バッチファイルの作成

  1. テキストエディタを開きます。
  2. 以下の内容をコピーして、ペーストします。
right_click_windows10.bat
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
@echo off
goto check_Permissions

:check_Permissions
    net session >nul 2>&1
    if %errorLevel% == 0 (
        echo ***********************************************************************
        echo 管理者権限が検出されました。スクリプトを続行しています...
        echo ***********************************************************************
        goto run_Script
    ) else (
        echo ***********************************************************************
        echo 管理者以外の権限が検出されました。管理者権限でスクリプトを再起動しています...
        echo プロンプトが表示されたら、続行、または管理者パスワードを入力してください。
        echo ***********************************************************************
        pause
        powershell -Command "Start-Process -Verb runAs '%comspec%' '/c %~dpnx0'"

        exit /B
    )

:run_Script
    setlocal

    set "KEY_NAME=HKEY_CURRENT_USER\Software\Classes\CLSID\{86ca1aa0-34aa-4e8b-a509-50c905bae2a2}"
    set "target=%KEY_NAME%\InprocServer32"

    reg query "%target%" /v "" >nul 2>&1
    if %errorlevel% equ 0 (
        reg delete "%KEY_NAME%" /f >nul 2>&1
        echo ***********************************************************************
        echo 右クリックを押したときの動作をwindows11仕様にしました。
        echo 変更を有効にするにはPCを再起動する必要があります。
        echo ***********************************************************************
        pause
    ) else (
        reg add "%target%" /ve /t REG_SZ /d "" /f >nul 2>&1
        echo ***********************************************************************
        echo 右クリックを押したときの動作をwindows10以前の仕様に戻しました。
        echo 変更を有効にするにはPCを再起動する必要があります。
        echo ***********************************************************************
        pause
    )
    set /p "restart=今すぐ再起動しますか？ (y/n) "
    if /i "%restart%"=="y" (
        shutdown /r /t 0
    ) else (
        echo 次回起動時に設定が反映されます。
        pause
    )

    endlocal
  1. ファイルを保存します。ファイル名はright_click_windows10.batとします。
  2. ファイルをダブルクリックして実行します。
  3. 管理者権限で実行するかどうか確認されるので、管理者権限で実行します。
  4. プロンプトが表示されたら、yを入力してPCを再起動します。
  5. 再起動後、右クリックの動作がWindows10のようになっていることを確認します。

手動で変更する方法

手動で変更する方法もあります。

  1. Win + R キーを押して、regeditと入力して、Enterキーを押します。
  2. HKEY_CURRENT_USER\Software\Classes\CLSIDに移動します。
  3. {86ca1aa0-34aa-4e8b-a509-50c905bae2a2}を右クリックして、新規 -> キーを選択して、InprocServer32と入力します。
  4. PCを再起動します。
  5. 再起動後、右クリックの動作がWindows10のようになっていることを確認します。
  6. 変更を元に戻す場合は、InprocServer32を削除します。
  7. PCを再起動します。
  8. 再起動後、右クリックの動作がWindows11のようになっていることを確認します。

まとめ

Windows11の右クリックの動作をWindows10のように変更する方法を説明しました。 バッチファイルを使う方法は、一括で変更できるので便利です。 手動で変更する方法もありますので、お好みの方法で変更してください。

コメント